home *** CD-ROM | disk | FTP | other *** search
/ Experimental BBS Explossion 3 / Experimental BBS Explossion III.iso / c / modex104.zip / C_UTILS.ASM < prev    next >
Assembly Source File  |  1993-05-14  |  9KB  |  406 lines
  1. ;=======================================================
  2. ;===  C_UTILS.ASM  - Asm Utilities for C/C++         ===
  3. ;=======================================================
  4.  
  5.     PAGE    255, 132
  6.  
  7.     .MODEL Medium
  8.     .286
  9.  
  10.     ; ==== MACROS ====
  11.  
  12.     ; macros to PUSH and POP multiple registers
  13.  
  14. PUSHx MACRO R1, R2, R3, R4, R5, R6, R7, R8
  15.     IFNB <R1>
  16.         push    R1                ; Save R1
  17.         PUSHx    R2, R3, R4, R5, R6, R7, R8
  18.     ENDIF
  19. ENDM
  20.  
  21. POPx MACRO R1, R2, R3, R4, R5, R6, R7, R8
  22.     IFNB <R1>
  23.         pop        R1                ; Restore R1
  24.         POPx    R2, R3, R4, R5, R6, R7, R8
  25.     ENDIF
  26. ENDM
  27.  
  28.     ; Macro to Clear a Register to 0
  29.  
  30. CLR MACRO Register
  31.     xor        Register, Register        ; Set Register = 0
  32. ENDM
  33.  
  34.     ; Macros to Decrement Counter & Jump on Condition
  35.  
  36. LOOPx MACRO Register, Destination
  37.     dec        Register                ; Counter--
  38.     jnz        Destination                ; Jump if not 0
  39. ENDM
  40.  
  41. LOOPjz MACRO Register, Destination
  42.     dec        Register                ; Counter--
  43.     jz        Destination                ; Jump if 0
  44. ENDM
  45.  
  46.  
  47.     ; ==== General Constants ====
  48.  
  49.     False    EQU    0
  50.     True    EQU    -1
  51.     nil        EQU 0
  52.  
  53.     b        EQU    BYTE PTR
  54.     w        EQU    WORD PTR
  55.     d        EQU    DWORD PTR
  56.     o        EQU    OFFSET
  57.     f        EQU FAR PTR
  58.     s        EQU    SHORT
  59.     ?x4        EQU <?,?,?,?>
  60.     ?x3        EQU <?,?,?>
  61.  
  62.  
  63.     .Data
  64.  
  65.     EVEN
  66.  
  67. RND_Seed    DW    7397, 29447, 802
  68. RND_Mult    DW    179, 183, 182
  69. RND_ModV    DW    32771, 32779, 32783
  70.  
  71. CR_LF        DB    13, 10            ; the CRLF data
  72.  
  73.     .Code
  74.  
  75. ;===========================================
  76. ;void far pascal dos_print  (far char *Text)
  77. ;===========================================
  78. ;
  79. ; - Print Text Directly to DOS console w/ CR/LF
  80. ;
  81.  
  82.     PUBLIC    DOS_PRINT
  83.  
  84. DP_Stack    STRUC
  85.                 DW    ?x4    ; DI, SI, DS, BP
  86.                 DD    ?    ; Caller
  87.     DP_Text        DD    ?    ; Far Address of Text to print
  88. DP_Stack    ENDS
  89.  
  90.  
  91. DOS_PRINT     PROC     FAR
  92.                
  93.     PUSHx    BP, DS, SI, DI        ; Preserve Important Registers
  94.     mov        BP, SP                ; Set up Stack Frame
  95.  
  96.     lds     DX, [BP].DP_Text    ; Get Addr of Text$ descriptor
  97.  
  98.     ; Compute Length of string
  99.  
  100.     CLR        CX                    ; Length = 0
  101.     mov        SI, DX                ; DS:SI = String data
  102.  
  103. @@DP_Scan_it:
  104.     
  105.     cmp        b [SI], 0            ; Null Byte found?
  106.     je        @@DP_Got_Len        ; exit loop if so
  107.  
  108.     inc        CX                    ; Len++
  109.     inc        SI                    ; Point to next char
  110.     jmp        s @@DP_Scan_it        ; check again...
  111.  
  112. @@DP_Got_len:
  113.  
  114.     jcxz    @No_Print            ; Don't Print if empty
  115.  
  116.     mov        BX, 1                ; 1= DOS Handle for Display
  117.     mov        AH, 40h                ; Write Text Function
  118.     int        21h                    ; Call DOS to do it
  119.  
  120. @No_Print:
  121.     mov        AX, SEG DGROUP        ; Restore DGroup
  122.     mov        DS, AX
  123.  
  124.     mov        DX, o CR_LF            ; Get Addr of CR/LF pair
  125.     mov        CX, 2                ; 2 Characters to Write        
  126.     mov        BX, 1                ; 1= DOS Handle for Display
  127.  
  128.     mov        AH, 40h                ; Write Text Function
  129.     int        21h                    ; Call DOS to do it
  130.  
  131.     cld                            ; Reset Direction Flag        
  132.     POPx    DI, SI, DS, BP        ; Restore Saved Registers
  133.     ret        4                    ; Exit & Clean Up Stack
  134.  
  135. DOS_PRINT     ENDP
  136.  
  137.  
  138. ;===========================================
  139. ;void far pascal dos_prints (char far *Text)
  140. ;===========================================
  141. ; 
  142. ; Print Text Directly to DOS console 
  143. ; without a trailing CR/LF
  144. ;
  145.  
  146.     PUBLIC    DOS_PRINTS
  147.  
  148. DOS_PRINTS     PROC     FAR
  149.  
  150.     PUSHx    BP, DS, SI, DI        ; Preserve Important Registers
  151.     mov        BP, SP                ; Set up Stack Frame
  152.  
  153.     lds     DX, [BP].DP_Text    ; Get Addr of Text$ descriptor
  154.  
  155.     ; Compute Length of string
  156.  
  157.     CLR        CX                    ; Length = 0
  158.     mov        SI, DX                ; DS:SI = String data
  159.  
  160. @@DPS_Scan_it:
  161.     
  162.     cmp        b [SI], 0            ; Null Byte found?
  163.     je        @@DPS_Got_Len        ; exit loop if so
  164.  
  165.     inc        CX                    ; Len++
  166.     inc        SI                    ; Point to next char
  167.     jmp        s @@DPS_Scan_it        ; check again...
  168.  
  169. @@DPS_Got_len:
  170.  
  171.     jcxz    @DPS_Exit            ; Don't Print if empty
  172.  
  173.     mov        BX, 1                ; 1= DOS Handle for Display
  174.     mov        AH, 40h                ; Write Text Function
  175.     int        21h                    ; Call DOS to do it
  176.  
  177. @DPS_Exit:
  178.     cld                              ; Reset Direction Flag        
  179.     POPx    DI, SI, DS, BP        ; Restore Saved Registers
  180.     ret        2                    ; Exit & Clean Up Stack
  181.  
  182. DOS_PRINTS     ENDP
  183.  
  184.  
  185. ;=========================================
  186. ;void far pascal set_video_mode (int Mode)
  187. ;=========================================
  188. ;
  189. ; Sets the Video Mode through the BIOS
  190. ;
  191.  
  192.     PUBLIC    SET_VIDEO_MODE
  193.  
  194. SVM_Stack    STRUC
  195.                 DW    ?x4    ; DI, SI, DS, BP
  196.                 DD    ?    ; Caller
  197.     SVM_Mode    DB    ?,? ; Desired Video Mode
  198. SVM_Stack    ENDS
  199.  
  200.  
  201. SET_VIDEO_MODE    PROC    FAR
  202.  
  203.     PUSHx    BP, DS, SI, DI        ; Preserve Important Registers
  204.     mov        BP, SP                ; Set up Stack Frame
  205.  
  206.     CLR        AH                    ; Function 0
  207.     mov        AL, [BP].SVM_Mode    ; Get Mode #
  208.  
  209.     int        10H                    ; Change Video Modes
  210.  
  211. @SVM_Exit:
  212.     POPx    DI, SI, DS, BP        ; Restore Saved Registers
  213.     ret        2                    ; Exit & Clean Up Stack
  214.  
  215. SET_VIDEO_MODE    ENDP
  216.  
  217.  
  218. ;===================================
  219. ;int far pascal scan_keyboard (void)
  220. ;===================================
  221. ;
  222. ; Function to scan keyboard for a pressed key
  223. ;
  224.  
  225.     PUBLIC    SCAN_KEYBOARD
  226.  
  227. SCAN_KEYBOARD    PROC    FAR
  228.  
  229.     PUSHx    BP, DS, SI, DI        ; Preserve Important Registers
  230.  
  231.     mov        AH, 01H                ; Function #1
  232.     INT        16H                    ; Call Keyboard Driver
  233.     JZ        @SK_NO_KEY            ; Exit if Zero flag set
  234.  
  235.     mov        AH,    00H                ; Remove Key from Buffer
  236.     INT        16H                    ; Get Keycode in AX
  237.  
  238.     OR        AL, AL                ; Low Byte Set (Ascii?)
  239.     JZ        @SK_Exit            ; if not, it's a F-Key
  240.  
  241.     CLR        AH                    ; Clear ScanCode if Ascii
  242.     JMP        s @SK_Exit            ; Return Key in AX
  243.  
  244. @SK_NO_KEY:
  245.     CLR        AX                    ; Return Nil (no Keypress)
  246.  
  247. @SK_Exit:
  248.     cld                            ; Reset Direction Flag        
  249.     POPx    DI, SI, DS, BP        ; Restore Saved Registers
  250.     ret                            ; Exit & Clean Up Stack
  251.  
  252. SCAN_KEYBOARD    ENDP
  253.  
  254.  
  255. ;========================================
  256. ;int far pascal random_int (int MaxValue)
  257. ;========================================
  258. ;
  259. ; Returns a pseudo-random number in the range of (0.. MaxInt-1)
  260. ;
  261.  
  262.  
  263.     PUBLIC    RANDOM_INT
  264.  
  265. RI_Stack    STRUC
  266.                 DW    ?    ; BP
  267.                 DD    ?    ; Caller
  268.     RI_MaxVal    DW    ?    ; Maximum Value to Return + 1
  269. RI_Stack    ENDS
  270.  
  271.  
  272. RANDOM_INT    PROC    FAR
  273.  
  274.     push    BP                    ; Preserve Important Registers
  275.     mov        BP, SP                ; Set up Stack Frame
  276.  
  277.        CLR        BX                    ; BX is the data index
  278.     CLR        CX                      ; CX is the accumulator
  279.  
  280. REPT 3
  281.       mov        AX, RND_Seed[BX]    ; load the initial seed
  282.     mul        RND_Mult[BX]        ; multiply it
  283.     div        RND_ModV[BX]        ; and obtain the Mod value
  284.     mov        RND_Seed[BX], DX    ; save that for the next time
  285.  
  286.     add        CX, DX                ; add it into the accumulator
  287.     inc        BX
  288.     inc        BX                  ; point to the next set of values
  289. ENDM
  290.  
  291.     mov        AX, CX                ; AX = Random #
  292.     CLR        DX                    ; DX = 0
  293.     div        [BP].RI_MaxVal        ; DX = DX:AX / MAxVal Remainder
  294.  
  295.     mov        AX, DX
  296.  
  297.     pop        BP                    ; Restore BP
  298.     ret        2                    ; back to BASIC with AX holding the result
  299.  
  300. RANDOM_INT    ENDP
  301.  
  302.  
  303. ;==================================
  304. ;void far pascal init_random (void)
  305. ;==================================
  306. ;
  307. ; Scrambles the psuedo-random number sequence
  308. ; (XOR's the seed value with the timer)
  309. ;
  310.  
  311.     PUBLIC    INIT_RANDOM
  312.  
  313. INIT_RANDOM    PROC    FAR
  314.  
  315.     CLR        AX                    ; Segment = 0000
  316.     mov        ES, AX
  317.     mov        AX, ES:[046Ch]      ; Get Timer Lo Word
  318.  
  319.     xor        RND_Seed, AX        ; Scramble 1st Seed
  320.  
  321.     ret                            ; Exit & Clean Up Stack
  322.  
  323. INIT_RANDOM    ENDP
  324.  
  325. ;=========================================
  326. ;int far pascal int_sqr (int X, int Round)
  327. ;=========================================
  328. ;
  329. ; Returns the Integer Square Root of (X)
  330. ; Round allows the return value to be rounded to the 
  331. ; nearest integer value by passing 0x80.  Passing 0
  332. ; return the Integer Portion only.  The rounding amound is
  333. ; a number from 0 to 1 multiplied by 256, thus 
  334. ; 0.5 * 0x100 = 0x80!
  335. ;
  336.  
  337. ISQ_Stack    STRUC
  338.                     DW    ?,?    ; BP, DI
  339.                     DD    ?    ; Caller
  340.     ISQ_Round        DW    ?    ; Amount to Round Result * 256
  341.     ISQ_X            DW    ?    ; "X"
  342. ISQ_Stack    ENDS
  343.  
  344.     PUBLIC    INT_SQR
  345.  
  346. INT_SQR        PROC    FAR
  347.  
  348.     PUSHx   BP, DI                ; Save BP
  349.     mov     BP, SP                ; Set up Stack Frame
  350.  
  351.      xor     AX, AX                ; {xor eax,eax}
  352.     xor     DX, DX                ; {xor edx,edx}
  353.     mov     DI, [BP].ISQ_X        ; {mov edi,x}
  354.  
  355.     mov     CX, 16                ; {mov cx, 32}
  356.  
  357. @ISQ_L:
  358.  
  359.     shl     DI, 1                ; {shl edi,1}
  360.     rcl     DX, 1                ; {rcl edx,1}
  361.     shl     DI, 1                ; {shl edi,1}
  362.     rcl     DX, 1                ; {rcl edx,1}
  363.     shl     AX, 1                ; {shl eax,1}
  364.     mov     BX, AX                ; {mov ebx,eax}
  365.     shl     BX, 1                ; {shl ebx,1}
  366.     inc     BX                     ; {inc ebx}
  367.     cmp     DX, BX                ; {cmp edx,ebx}
  368.     jl         @ISQ_S
  369.  
  370.       sub     DX, BX                ; {sub edx,ebx}
  371.     inc     AX                     ; {inc eax}
  372.  
  373. @ISQ_S: 
  374.     loop     @ISQ_L
  375.  
  376.       add     ax, [BP].ISQ_Round    ; {add eax,$00008000}  
  377.                                 ; {*round* result in hi word: ie. +0.5}
  378.     shr     ax, 8                ; {shr eax,16}  {to ax (result)}
  379.  
  380.     POPx    DI, BP                ; Restore Registers    
  381.     ret        4                    ; Exit
  382.  
  383. INT_SQR        ENDP
  384.  
  385. ;=================================
  386. ;int far pascal timer_count (void)
  387. ;=================================
  388. ;
  389. ; Returns the current timer value as an integer/long integer
  390. ;
  391.  
  392.     PUBLIC  TIMER_COUNT
  393.  
  394. TIMER_COUNT      PROC    FAR
  395.  
  396.     CLR        AX                    ; Segment = 0000
  397.     mov        ES, AX
  398.     mov        AX, ES:[046Ch]      ; Get Timer Lo Word
  399.     mov        DX, ES:[046Eh]        ; Get Timer Hi Word
  400.     ret                            ; Exit & Clean Up Stack
  401.  
  402. TIMER_COUNT      ENDP
  403.  
  404.  
  405.     END
  406.